Indicateur PRT pour afficher tous les niveaux symboliques

Pour faire simple


y=6

x=(Round((Close-y/2*100)/100))*100
For i= 1 to y
x = x +100
DRAWHLINE(x) COLOURED(117, 0, 158)
Next
RETURN

Il suffit de changer la valeur y selon le nombre de lignes souhaitées

Bonne soirée tout le monde

Je le refais, j'ai oublié un petit morceau

DEFPARAM CALCULATEONLASTBARS = 1

y=6

x=(Round((Close-y/2*100)/100))*100
For i= 1 to y
x = x +100
DRAWHLINE(x) COLOURED(117, 0, 158)
Next
RETURN

Bonjour Bab

Merci pour le partage.

J'ai testé ton code, il fonctionne mais je pense qu'il manque aussi les zones 250 et 750 car les 500 et 1000 sont déjà repris par ton code.

Pour ces 4 zones il faudrait pouvoir les différencier avec un trait un peu plus épais.

Pandino_cz, on ne peut malheureusement pas changer l'épaisseur de la ligne

edit : Je viens de vérifier sur la V11 et il semblerait que l'on peut maintenant
en stylant la ligne STYLE(LINE,2)

Hello Thierry,

Avec "STYLE" tu peux modifier l'épaisseur de la ligne. Si on parle bien de la même chose.

https://www.prorealcode.com/documentation/style/

Si vous ne parliez pas de ça, désolé de mon intervention
A+

nico1119 Oui c'est bien cela ! Je viens de m'en rendre compte !

Merci à toi

Pas de doute, c'est NOEL !!!

ça m'énervait tellement de pas pouvoir assigner une épaisseur...

De rien Thierry!

Bon, on ne peut pas passer l'épaisseur en variable...

Jamais content !

Merci Thierry 29
Je vais donc garder le code de Pat95162

Et voilà

DEFPARAM CALCULATEONLASTBARS = 1

y=10
x=(Round((Close-y/2*100)/100))*100
For i= 1 to y
x = x + 100
DRAWHLINE(x) COLOURED(0, 0, 255) STYLE(LINE,1) //Bleu
Next

x=(Round((Close-y/2*100)/100))*100
For i= 1 to y
x = x + 100
z = (Round(x/1000.00)) * 1000.00
DRAWHLINE(z) COLOURED(255, 0, 0) STYLE(LINE,2)//Rouge
DRAWHLINE(z+250) COLOURED(255, 0, 0) STYLE(LINE,2)//Rouge
DRAWHLINE(z+500) COLOURED(255, 0, 0) STYLE(LINE,2)//Rouge
DRAWHLINE(z+750) COLOURED(255, 0, 0) STYLE(LINE,2)//Rouge
NEXT

RETURN


Bonne fin d'année à tous

Merci Bab, je vais tester.

Bon réveillon à tout le monde!

Bonjour
Je vous souhaite à toutes et tous une bonne et merveilleuse année.
Je suis une buse en informatique et la panoplie de prorealcode semble un peu limité.
Question à ceux qui touchent à la programmation :
La 7eme ligne du code ne fonctionne pas en partie sur "a = 500 or a = 750"
Si un bon samaritain peut m'ouvrir les yeux en me donnant la lumière , je lui fais une bise virtuelle.
Merci et bonne journée


DEFPARAM CALCULATEONLASTBARS = 1
y = 20
x = (Round((Close-y/4*100)/100))*100
For i= 1 to y
x = x + 50
a = x - Round( x / 1000)*1000
if a = 0 or a = 250 or a = 500 or a = 750 then
DRAWHLINE(x) COLOURED(0, 0, 255) STYLE(LINE,2) //Bleu
elsif a - Round( a / 100)*100 = 0 then
DRAWHLINE(x) COLOURED(0, 0, 255) STYLE(LINE,1) //Bleu
endif
Next
RETURN

Y a t il quelqu'un dans l'avion? :roll:
Je suis friand de savoir
Merci et bonne journée.

Bonjour ozmirak ainsi qu’à tous les autres traders. Vous avez fait des modifs en plus du code qu’avais fournit ozmirak d’ou la question : qu’est-ce qu’on fait maintenant ? Est-ce qu’on reste sur le 1er code ou bien faut-il adapter les améliorations sur le 1er code avec comme 2ème question est-ce qu’un membre informaticien peut créer un code qui reprenne le code de ozmirak avec les améliorations en plus ? Merci à vous tous....

Bonjour,
Voici l'indicateur final amélioré, plus compacte, beaucoup plus rapide et tenant compte de toutes les remarques qu'il y a eu sur cette file. à vous tous.

Code : #

defparam drawonlastbaronly = true
defparam CalculateOnLastBars = 10

//Violet
VioletR=128
VioletG=0
VioletB=255
//Orange
OrangeR=255
OrangeG=128
OrangeB=0
//Noir
NoirR=0
NoirG=0
NoirB=0
//Bleu
BleuR=0
BleuG=168
BleuB=255
//Vert
VertR=128
VertG=255
VertB=0
//Jaune
JauneR=128
JauneG=255
JauneB=0

If Close < 2500  Then
//------------------------------------Tous Les 25 Pour Les Marchés < 2500 --------------
//y=6 pour tracer -3 +3 autour du Round du Close
y=8
X25=(Round((Close-y/2*25)/25))*25
For I = 1 To y
X25 =  X25 + 25
DrawHLine (X25) Coloured(JauneR,JauneG,JauneB) STYLE(DOTTEDLINE,1)
DRAWTEXT("                    #X25#",barindex,X25+1,SansSerif,Bold,14) Coloured(JauneR,JauneG,JauneB)
Next
EndIf

//------------------------------------Tous Les 50  Quelque Soit Le Marché-----------------
//------------------------------------Tous Les 100 Quelque Soit Le Marché-----------------
//y=6 pour tracer -3 +3 autour du Round du Close
y=6
X100=(Round((Close-y/2*100)/100))*100
For I = 1 To y
X100 = X100 + 100
DrawHLine (X100) Coloured(BleuR,BleuG,BleuB) STYLE(LINE,2)
DRAWTEXT("                    #X100#",barindex,X100+1,SansSerif,Bold,14) Coloured(BleuR,BleuG,BleuB)
X50 =  X100 + 50
DrawHLine (X50) Coloured(VertR,VertG,VertB) STYLE(LINE,2)
DRAWTEXT("                    #X50#",barindex,X50+1,SansSerif,Bold,14) Coloured(VertR,VertG,VertB)
Next

//------------------------------------Tous Les 250 Quelque Soit Le Marché-----------------
//------------------------------------Tous Les 500 Quelque Soit Le Marché-----------------
//y=6 pour tracer -3 +3 autour du Round du Close
y=6
X500=(Round((Close-y/2*500)/500))*500
For I = 1 To y
X500 = X500 + 500
DrawHLine (X500) Coloured(VioletR,VioletG,VioletB) STYLE(LINE,3)
DRAWTEXT("                    #X500#",barindex,X500+1,SansSerif,Bold,14) Coloured(VioletR,VioletG,VioletB)
X250 = X500 + 250
DrawHLine (X250) Coloured(OrangeR,OrangeG,OrangeB) STYLE(LINE,3)
DRAWTEXT("                    #X250#",barindex,X250+1,SansSerif,Bold,14) Coloured(OrangeR,OrangeG,OrangeB)
Next

//------------------------------------Tous Les 1000 Quelque Soit Le Marché-----------------
//y=4 pour tracer -2 +2 autour du Round du Close
y=4
X1000=(Round((Close-y/2*1000)/1000))*1000
For I = 1 To y
X1000 = X1000 + 1000
DrawHLine (X1000) Coloured(NoirR,NoirG,NoirB) STYLE(LINE,4)
DRAWTEXT("                    #X1000#",barindex,X1000+1,SansSerif,Bold,14) Coloured(NoirR,NoirG,NoirB)
Next

Return

Je vous souhaite une bonne utilisation.

Merci Ozmizrak, je vais le tester

Bonjour Ozmizrak et merci

Bonjour,
Un immense pour le boulot fourni, à commencer par Oz
L'indicateur fonctionne parfaitement pour moi. Je l'utilise depuis la première version.