Méthode alexLeBreton

Bonjour à tous,

Alex nous partage sur la file du jour sa méthode, et je la trouve super. Du coup je vous la partage :



file-cac40-du-mercredi-09-fevrier-2022- ... l#p1758752

Code : #

m1 = average[20](close)
m2 = exponentialaverage[20](close)
a = m2 - m1
return a

il suffit de regarder ce qui se passe au changement de "perle", cela donne à priori de bons points à l'achat ou à la vente. Plus il y a de perles de la même couleur avant et plus le signal est bon. En gros cela mesure l'écart de vitesse du marché dans le temps.




Amélioration :
file-cac40-du-jeudi-10-fevrier-2022-t47 ... l#p1759778

pour ceux que cela intéresse, une mise à jour de mon indicateur d'accélération. Plus besoin de suivre le changement de couleur maintenant. Cela dessine également sur le graphe les achats / ventes.

Code : #

quality=5

m1 = average[20](close)
m2 = exponentialaverage[20](close)
a = m2 - m1
rge = averagetruerange[10](close)
dir = 0

flag1 = 1
for i = 1 to quality
if ( a > a[i+1] ) then
flag1 = 0
break
endif
next

if ( a > a[1] and flag1 = 1 ) then
drawarrowup(barindex[1], high[1] - 3 * rge ) coloured(200,250,200,200)
dir = 1
endif

flag2 = 1
for i = 1 to quality
if ( a < a[i+1] ) then
flag2 = 0
break
endif
next

if ( a < a[1] and flag2 = 1 ) then
drawarrowdown(barindex[1], low + 3 * rge ) coloured(250,200,200,200)
dir = -1
endif

return dir

merci Alex !

Bon le backtest n'est pas aussi fiable en automatique que j'ai pu l'écrire. Il faut l'associer aux resistances, supports et tendance (je ne sais pas programmer ça et ce serait trop long...).

Tu l'utilises sur quelle ut ? Ce que je fais :
- prise de position en petite ut (25t, 50t)
- Et j'essaye de voir en 5Mn l'accélaration pour être dans le bon sens.

Réponse Alex

"
je l'ai utilisé sur le 5mn ce matin, par contre j'ai vu qu'il avait donné un signal top sur le 4H aussi. Mais bon c'est peut-être juste favorable à la période, difficile à dire si cela tient vraiment la route sur la durée, je vais regarder en auto ce que cela donne.
"

Alex,

Est-ce que tu sais si il y a moyen de faire disparaitre la ligne zero du graph principal ?
En effet, lors d'un redimensionnement automatique, prt la prend en compte et tu as une échelle qui part de 0 jusqu'à la valeur actuelle du prix...

Je ne sais pas si faire disparaitre la ligne zero permettrait de ne plus avoir ce problème...

normalement y a pas de ligne zéro, sauf si tu l'as configurer dans l'indicateur (voir les propriétés)

Capture.PNG (17.15 Kio) Vu 628 fois

si tu veux juste voir les flèches dans le graphe sans avoir un changement d'échelle, tu mets "return" à la fin au lieu de "return dir"

en fait je n'ai pas de ligne pour l'indicateur dans un panneau séparé :

Screenshot 2022-02-14 115031.png (26.28 Kio) Vu 621 fois

en revanche sur le graphique, si :

Screenshot 2022-02-14 114847.png (33.66 Kio) Vu 621 fois

Screenshot 2022-02-14 115055.png (33.45 Kio) Vu 621 fois

Bon je crois que tu as répondu à ma question en même temps que je postait...

je teste

Super, ça marche

Merci

petite mise à jour pour ne prendre que la bonne tranche horaire

// Version 1.1

quality=5

m1 = average[20](close)
m2 = exponentialaverage[20](close)
a = m2 - m1
rge = averagetruerange[10](close)
dir = 0

flag1 = 1
for i = 1 to quality
if ( a > a[i+1] ) then
flag1 = 0
break
endif
next

if ( a > a[1] and flag1 = 1 ) then
dir = 1
endif

flag2 = 1
for i = 1 to quality
if ( a < a[i+1] ) then
flag2 = 0
break
endif
next

if ( a < a[1] and flag2 = 1 ) then
dir = -1
endif

if ( hour > 22 or hour < 8 ) then
dir = 0
endif

if ( dir = 1 ) then
drawarrowup(barindex[1], high - rge ) coloured(200,250,200,200)
endif
if ( dir = -1 ) then
drawarrowdown(barindex[1], low + rge ) coloured(250,200,200,200)
endif

// mode indicateur
return dir as "acceleration"

--> Avec le AS cela corrige le problème de mise à l'échelle

Top, je teste.

T'as même ajouté le mode flèche, excellent

edit : merci pour la modif

nop ça corrige pas la mise à l'échelle chez moi...

j'ai créé un indicateur de base

Code : #

// ACCELERATOR-INDIC

quality=5

m1 = average[20](close)
m2 = exponentialaverage[20](close)
a = m2 - m1

dir = 0

flag1 = 1
for i = 1 to quality
if ( a[i] > a[i+1] ) then
flag1 = 0
break
endif
next

if ( a > a[1] and flag1 = 1 ) then
dir = 1
endif

flag2 = 1
for i = 1 to quality
if ( a[i] < a[i+1] ) then
flag2 = 0
break
endif
next

if ( a < a[1] and flag2 = 1 ) then
dir = -1
endif

if ( hour > 22 or hour < 8 ) then
dir = 0
endif

return dir as "acceleration"

Puis un indicateur dédié aux flèches qui utilise l'indicateur de base

Code : #

dir = CALL "ACCELERATOR-INDIC"

rge = averagetruerange[10](close)

if ( dir = 1 ) then
drawarrowup(barindex[1], high - rge ) coloured(200,250,200,200)
endif
if ( dir = -1 ) then
drawarrowdown(barindex[1], low + rge ) coloured(250,200,200,200)
endif

return

comme cela si on modifie l'indicateur de base, pas la peine de changer l'indicateur pour les flèches.

Super.
Bonne idée.

Pour info, dans ton code de base sur ton post tu l'as copié deux fois

Perso j'ai changé les couleurs de flèches, au cas où quelqu'un ne saurait pas le faire...

Code : #

//ACCELERATOR-ARROW
dir = CALL "ACCELERATOR-INDIC"

rge = averagetruerange[10](close)

if ( dir = 1 ) then
//couleur origine fleche UP : coloured(200,250,200,200)
drawarrowup(barindex[1], high - rge ) coloured(0,0,255)
endif
if ( dir = -1 ) then
//couleur origine fleche down : coloured(250,200,200,200)
drawarrowdown(barindex[1], low + rge ) coloured(255,0,0)
endif

return

Les codes couleurs :
https://www.prorealcode.com/documentation/coloured/

corrigé le doublon

mise à jour pour avoir un affichage de flèches mieux positionné, j'ai repris tes codes couleurs plus visibles

Code : #

// Version 1.1

dir = CALL "ACCELERATOR-INDIC"

rge = ( averagetruerange[10](close) / 2 )

if ( dir = 1 ) then
drawarrowup(barindex, high - rge - 20 ) coloured(0,0,255)
endif
if ( dir = -1 ) then
drawarrowdown(barindex, low + rge + 20 ) coloured(255,0,0)
endif

return

Comme ça on peut même modifier la valeur pour les placer où où on veut.

Super, merci !

voici sur le même principe l'"alexerator-zones" qui doit est utilisé sur le 5mn et le 1mn. Il faut mettre au moins 1000 unités pour que le calcul se fasse correctement

Code : #

// Version 1.0
// L'alexerator-zone sur détection par bande de couleur des zones d'achat et de ventes sur le 5mn et le 1mn

timeframe( 1 hours, updateonclose )

once dir1h = 0

m1h = average[20](close)
m2h = exponentialaverage[20](close)
ah = m2h - m1h

if ( ah > ah[1] ) then
dir1h = 1
endif

if ( ah < ah[1] ) then
dir1h = -1
endif

timeframe( 15 minutes )

dir15 = 0

m1 = average[20](close)
m2 = exponentialaverage[20](close)
a = m2 - m1

if ( a > a[1] and dir1h = 1 ) then
backgroundcolor( 0, 255, 0, 20 )
if ( close > open ) then
dir15 = 1
endif
endif

if ( a < a[1] and dir1h = -1 ) then
backgroundcolor( 255, 0, 0, 20 )
if ( close < open ) then
dir15 = -1
endif
endif

timeframe( default )

return

cela s'ajoute sur la zone de prix.

principe :

sur fond vert, prendre un setup à l'achat
sur fond rouge, prendre un setup à la vente

exemple un rsi sur fond vert qui sort de sa zone de survente est un setup d'achat