ProRealTime
Pour discuter sur l’interface de ProRealTime Software, nos configurations graphiques...
Répondre • Page 1 sur 1

Loi de Dow : est-ce codable sous PRT

par plataxis » 25 mars 2017 21:18

Bonjour,

Je patine avec l'instruction donnant la valeur la plus haute de prix sur N barres en arrière :

Code : #

haut = highest[N](high)
Le problème avec ce code est que lorsque l'on veut acheter parce qu'un nouveau plus haut a été franchi, et bien ce nouveau plus haut devient le nouveau plus haut enregistré N barres en arrière.

Autrement dit, je ne suis pas sûr que ce soit la bonne méthode pour coder la Loi de Daw : c'est assez difficile de modéliser un code indiquant qu'un nouveau plus haut a été franchi, même si l'on est en cours de retracement.

Quelqu'un s'est-il déjà penché sur la question ?

Re: Loi de Daw : est-ce codable sous PRT

par Edd » 25 mars 2017 23:37

Salut,
pour récupérer un signal avec cette instruction il suffit de décaler le "high" de quelques barres. Exemple 5 barres , "high[5]"

Code : #

resistance= highest[100](high[5])
return resistance
DOW.png

Re: Loi de Daw : est-ce codable sous PRT

par kero » 25 mars 2017 23:49

C'est ça. Ton "highest" doit avoir un minimum d'ancienneté pour que son franchissement soit significatif. Sinon, il se peut que tu ne fasses que franchir la barre précédente, ce qui n'est pas un signal (au sens de la loi de Dow que tu évoques).

À toi de définir l'ancienneté minimale qui t'intéresse (et vérifier ensuite que ce niveau n'a pas été franchi entretemps).

Re: Loi de Dow : est-ce codable sous PRT

par plataxis » 26 mars 2017 22:40

Génial !

J'adore ce code !

Code : #

historique=100
decalage=5

resistance = highest[historique](high[decalage])
support = lowest[historique](low[decalage])

return resistance, support


Re: Loi de Dow : est-ce codable sous PRT

par plataxis » 29 mars 2017 23:22

Amélioration :
Spoiler:

Code : #

once historique=100
once decalage=5
haussier = 0
baissier = 0
once marge = 3

resistancehaute = highest[historique](high[decalage])
resistancebasse = highest[historique](low[decalage])

supportbas = lowest[historique](low[decalage])
supporthaut = lowest[historique](high[decalage])

c1 = highest[historique](high) > resistancehaute
c2 = highest[historique](low) > resistancebasse
if C1 AND c2 then
baissier=0
haussier = 1
endif

c3 = lowest[historique](low) < supportbas
c4 = lowest[historique](high) < supporthaut
if c3 and c4 then
haussier=0
baissier = 1
endif

if haussier then
DRAWTEXT ("o",barindex[1],low[1]-marge)coloured(10,255,10)
elsif baissier then
DRAWTEXT ("o",barindex[1],high[1]+marge)coloured(255,10,10)
endif


return resistancehaute, resistancebasse, supportbas, supporthaut
Quelqu'un sait-il comment dessiner les petits ronds utilisés dans l'indicateur "parabolic SAR" ? J'ai contourné avec la lettre "o" mais c'est moins joli...

Re: Loi de Dow : est-ce codable sous PRT

par Edd » 30 mars 2017 08:24

plataxis a écrit : Quelqu'un sait-il comment dessiner les petits ronds utilisés dans l'indicateur "parabolic SAR" ? J'ai contourné avec la lettre "o" mais c'est moins joli...
Salut plataxis,
-tu ouvres la table des caractères (sous windows) : Windows + R , commande : CHARMAP , entrée.
-tu selectionnes le caractère voulu à copier
-et tu colles dans le code, rond ou carré:

Code : #

DRAWTEXT("▪"...
DRAWTEXT("•"...

Re: Loi de Dow : est-ce codable sous PRT

par plataxis » 01 avr. 2017 17:31

Joli !

Merci Edd !

Pour "lisser" les caractère j'ai utilisé une MM : sur la semaine c'est très joli !
Spoiler:

Code : #

once historique=100
once decalage=5
haussier = 0
baissier = 0


resistancehaute = highest[historique](high[decalage])
resistancebasse = highest[historique](low[decalage])

supportbas = lowest[historique](low[decalage])
supporthaut = lowest[historique](high[decalage])

c1 = highest[historique](high) > resistancehaute
c2 = highest[historique](low) > resistancebasse
if C1 AND c2 then
baissier=0
haussier = 1
endif

c3 = lowest[historique](low) < supportbas
c4 = lowest[historique](high) < supporthaut
if c3 and c4 then
haussier=0
baissier = 1
endif


if haussier then
DRAWTEXT("•",barindex[1],average[historique])coloured(10,255,10)
elsif baissier then
DRAWTEXT("•",barindex[1],average[historique])coloured(255,10,10)
endif


return resistancehaute coloured (10,255,10) as "resistance haute",resistancebasse coloured (255,10,1) as "resistance basse",supportbas coloured (10,255,10) as "support bas", supporthaut coloured (255,10,10) as "support haut"

Re: Loi de Dow : est-ce codable sous PRT

par plataxis » 01 avr. 2017 18:08

Etrange : j'ai tenté d'en faire un robot, et les ordres sont tous passés avec 2 bougies de décalage par rapport à mon indicateur, alors que c'est pourtant sur le même modèle !
Spoiler:

Code : #

defparam flatbefore=090000
defparam flatafter= 173000

once heuremax=163000
once historique=100
once decalage=5

haussier = 0
baissier = 0


resistancehaute = highest[historique](high[decalage])
resistancebasse = highest[historique](low[decalage])

supportbas = lowest[historique](low[decalage])
supporthaut = lowest[historique](high[decalage])

c1 = highest[historique](high) > resistancehaute
c2 = highest[historique](low) > resistancebasse


if C1 AND c2 then
baissier=0
haussier = 1
endif


c3 = lowest[historique](low) < supportbas
c4 = lowest[historique](high) < supporthaut


if c3 and c4 then
haussier=0
baissier = 1
endif




// Conditions pour ouvrir une position acheteuse
IF NOT LongOnMarket AND haussier=1 AND Time<heuremax THEN
BUY 1 CONTRACTS AT MARKET
ENDIF

// Conditions pour fermer une position acheteuse
If LongOnMarket AND haussier=0 THEN
SELL AT MARKET
ENDIF

// Conditions pour ouvrir une position en vente à découvert
IF NOT ShortOnMarket AND baissier=1 AND Time<heuremax THEN
SELLSHORT 1 CONTRACTS AT MARKET
ENDIF

// Conditions pour fermer une position en vente à découvert
IF ShortOnMarket AND baissier=0 THEN
EXITSHORT AT MARKET
ENDIF

// Stops et objectifs : entrez vos stops et vos objectifs ici

Re: Loi de Dow : est-ce codable sous PRT

par Balian » 28 oct. 2017 09:03

plataxis a écrit :Joli !

Merci Edd !

Pour "lisser" les caractère j'ai utilisé une MM : sur la semaine c'est très joli !
Spoiler:

Code : #

once historique=100
once decalage=5
haussier = 0
baissier = 0


resistancehaute = highest[historique](high[decalage])
resistancebasse = highest[historique](low[decalage])

supportbas = lowest[historique](low[decalage])
supporthaut = lowest[historique](high[decalage])

c1 = highest[historique](high) > resistancehaute
c2 = highest[historique](low) > resistancebasse
if C1 AND c2 then
baissier=0
haussier = 1
endif

c3 = lowest[historique](low) < supportbas
c4 = lowest[historique](high) < supporthaut
if c3 and c4 then
haussier=0
baissier = 1
endif


if haussier then
DRAWTEXT("•",barindex[1],average[historique])coloured(10,255,10)
elsif baissier then
DRAWTEXT("•",barindex[1],average[historique])coloured(255,10,10)
endif


return resistancehaute coloured (10,255,10) as "resistance haute",resistancebasse coloured (255,10,1) as "resistance basse",supportbas coloured (10,255,10) as "support bas", supporthaut coloured (255,10,10) as "support haut"
Pas certain de comprendre les couleurs dans ce cas ?

Re: Loi de Dow : est-ce codable sous PRT

par plataxis » 28 oct. 2017 11:41

Que veux-tu comprendre Balian ? J'ai codé une couleur haussière et une couleur baissière au pif, après tu peux changer de couleur si tu as d'autres préférences... (change les chiffres RGB entre 0 et 255)

Re: Loi de Dow : est-ce codable sous PRT

par Balian » 29 oct. 2017 22:04

Je ne suis pas très clair. Désolé. Lorsque je lancer l'indicateur, j'obtiens 2 courbes en haut des cours (une verte et une rouge) et 2 courbes en bas (même couleur). Je ne suis pas certain de comprendre pourquoi il y a les 2 courbes à chaque fois

Re: Loi de Dow : est-ce codable sous PRT

par plataxis » 29 oct. 2017 22:14

Les 2 du haut montrent les valeurs retenues pour la tendance haussière, les 2 du bas pour la tendance baissière. Celles qui progressent sont celles qui vont dans le sens du vent.

Re: Loi de Dow : est-ce codable sous PRT

par Balian » 30 oct. 2017 15:57

Ok merci

Sujets similaires
Méthode Loi de Dow sur le Dow Jones
Fichier(s) joint(s) par Jordi » 13 mai 2020 11:43 (7 Réponses)
Loi de Dow et échelle de temps pour validation
par Amarantine » 21 mars 2019 11:23 (6 Réponses)
Loi de Dow et échelle de temps pour validation
par Taylor » 21 mars 2019 11:23 (0 Réponses)
Indicateur Loi de Dow ou ZigZag avec affichage variations
Fichier(s) joint(s) par Ozmizrak » 28 nov. 2020 14:30 (3 Réponses)
Loi de Dow
par HellionReign » 08 juin 2021 19:13 (2 Réponses)
Vaut il mieux trader Mini Dow ou Micro Dow sur Futures?
par Papaours74 » 27 juin 2020 12:33 (10 Réponses)
La loi des séries?
par Amarantine » 01 déc. 2014 12:00 (3 Réponses)
Ouverture d'un compte réel IG et loi de l'AMF ?
par Benoist Rousseau » 23 févr. 2016 09:02 (3 Réponses)