Code : #
//Traçage de segments pour les 100 en jaune et des 250, 500 et 1000 en rose !
//Affichage du prix uniquement pour les multiples de 250 (et pour la médiane de j-1 arrondi en centaine)
//---On se base sur le prix médian/milieu du jour précédent
//---et on trace 10% du prix au-dessus et 10% du prix en-dessous
//@David
defparam drawonlastbaronly = true
//Voffset position Verticale du prix
//Hoffset position Horizontale du prix
Voffset = 5*pipsize
Hoffset = barindex - 50
//Calcul centaine --- on prend le milieu du jour précédent arrondi en centaine
centaine = round(((DHigh(1) + DLow(1)) / 2)/100) * 100
DRAWTEXT("#centaine#",Hoffset,centaine+Voffset,SansSerif,Bold,12)COLOURED(255,255,0) //affichage de la centaine médiane j-1
centaineInferieure = centaine //Variable pour les centaines inférieures à la médiane j-1
//Calcul millaine
millaine = round(centaine/1000) * 1000
millaineInferieure = millaine
for i = 1 to (centaine*10/100) /100 //on se base sur 10% du produit /100 pour savoir le nombre de centaines à tracer
if centaine mod 250 <> 0 then //on enlève tous les multiples de 250
DRAWSEGMENT(barindex - intradaybarindex, centaine, barindex, centaine)COLOURED(255,255,0)
endif
centaine = centaine + 100 //on incrémente par 100 pour passer aux lignes du dessus de la médiane j-1
if centaineInferieure mod 250 <> 0 then
DRAWSEGMENT(barindex - intradaybarindex, centaineInferieure, barindex, centaineInferieure)COLOURED(255,255,0)
endif
centaineInferieure = centaineInferieure - 100 //on décrémente par 100 pour passer aux lignes d'en dessous de la médiane j-1
next
for i = 1 to (centaine*10/100) /250 //on se base sur 10% du produit /250 pour savoir le nombre de millaines à tracer
if millaine mod 250 = 0 then //on prend uniquement les multiples de 250
DRAWSEGMENT(barindex - intradaybarindex, millaine, barindex, millaine)COLOURED(222,51,255)
DRAWTEXT("#millaine#",Hoffset,millaine+Voffset,SansSerif,Bold,12)COLOURED(222,51,255)
endif
millaine = millaine + 250
if millaineInferieure mod 250 = 0 then
DRAWSEGMENT(barindex - intradaybarindex, millaineInferieure, barindex, millaineInferieure)COLOURED(222,51,255)
DRAWTEXT("#millaineInferieure#",Hoffset,millaineInferieure+Voffset,SansSerif,Bold,12)COLOURED(222,51,255)
endif
millaineInferieure = millaineInferieure - 250
next
return
