PRT - Neutral Zone

Bonjour,

Voici un code prt indicateur pour créer une zone neutre où l'on n'intervient pas ou en connaissance de cause

Pour comprendre à quoi il sert et comment s'en servir je ne peux que vous renvoyer vers l'article de Ayame : Retour d’expériences et méthodologie d’un passionné

Je vous livre ici le code complet et n'oubliez pas de créer les variables qui vont avec, si vous n'avez pas l'âme d'un programmeur je vous donne également le lien vers mon OneDrive ou se trouve un fichier nommé Neutral Zone.itf que vous pouvez directement importer dans votre plateforme prorealtime.

NeutralZone.png (46.54 Kio) Vu 1560 fois

NeutralZoneOption.png (16.2 Kio) Vu 1560 fois

Le Code :

Code : #

// Author : RyanTrading
// Indicator Name : NeutralZone
// ProRealTime Version : 11
// Published for : AndLil

DEFPARAM DRAWONLASTBARONLY = FALSE

Drawed = 0

IF OPENTIME >= HeureOuverture and opentime < HeureOuverture + 25  then

OpenPrice = Open
OpenD = openday
OPenM = openmonth
OpenY = openYear

Date1 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + HeureOuverture
Date2 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + HeureFermeture
Date3 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + HeureFermeture -30000

IF NOT Drawed[1] THEN

IF Historique THEN

DRAWSEGMENT(BarIndex, OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255)
DRAWRECTANGLE(BarIndex, OpenPrice+PointsPipsNeutre, DateToBarIndex(Date2), OpenPrice-PointsPipsNeutre) COLOURED(140,172,255)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,Dialog,standard,12) COLOURED(140,172,255)

ELSE

IF OPENDAY = TODAY then
DRAWSEGMENT(BarIndex, OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255)
DRAWRECTANGLE(BarIndex, OpenPrice+PointsPipsNeutre, DateToBarIndex(Date2), OpenPrice-PointsPipsNeutre) COLOURED(140,172,255)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,Dialog,standard,12) COLOURED(140,172,255)
ENDIF

ENDIF

Drawed = 1

ENDIF
ENDIF

RETURN

Les variables à programmer :

NeutralZoneVar.png (116.31 Kio) Vu 1560 fois

Lien de téléchargement de l'indicateur directement prêt à être importé :

https://1drv.ms/u/s!AgURiMs5AHStgsRXEHtW2jyLL90Izw?e=hf0lmY

Voilà voilà

Merci beaucoup
cela va en aider plus qu'un qui n'y connait rien en programmation prt.

Ryan Merci pour ce partage

J'ajouterai que si tu veux remplir le rectangle avec une couleur, il faut assigner une couleur à la bordure (V11)

DRAWRECTANGLE(BarIndex, OpenPrice+PointsPipsNeutre, DateToBarIndex(Date2), OpenPrice-PointsPipsNeutre) COLOURED(140,172,255) bordercolor(0,0,0)

Tordu non ?

Merci, je vais tester cela.

Ah super Thierry je trouvais pas comment faire pour remplir le rectangle, je vais essayer ça , je m'attendais à une instruction FILL un truc du genre mais rien

Neutral Zone.png (10.04 Kio) Vu 1512 fois

Voilà ça donne beaucoup mieux

J'ai ajouté l'exportation dans le OneDrive : Neutral Zone 2.itf

Oui, c'est un peu curieux.

Du coup tu peux gérer l'alpha (la transparence) avec le quatrième paramètre de Coloured genre COLOURED(140,172,255,126)

Sympa le concept je vais l’installer merci

Bonjour à tous,

Je viens de revoir complètement le code et ajouté une option de transparence.

Neutral Zone Options.png (39.71 Kio) Vu 1454 fois

L'heure d'ouverture et de fermeture du marché se note maintenant de manière suivante :

08h00 --> 800 ou 0800 (Le 0 superflus sera automatiquement supprimé)
15h30 --> 1530
17h30 --> 1730
22h00 --> 2200
...

Attention que sur un TimeFrame en tick il sera extrêment rare quand les zones seront visibles car il est peu probable qu'une barre (chandelier) ouvre pile à l'heure spécifiée d'ouverture.

Donc les TimeFrame à privilégier sont donc 1min, 2min, 5min, 10min, 30min
et éventuellement 1h si vous avez des ouvertures à heure ronde exemple 08h00

La nouvelle option Transparence est exprimée en % et par défaut à 20

Le fichier sur OneDrive à été mis à jour : Neutral Zone.itf dans le dossier "Indicateurs prorealtime"

Lien vers mon OneDrive : https://1drv.ms/u/s!AgURiMs5AHStgsRXEHtW2jyLL90Izw?e=hf0lmY

Code : #

// Author : RyanTrading
// Indicator Name : Neutral Zone
// ProRealTime Version : 11
// Published for : AndLil - https://www.andlil.com/
// -------------------------------------------------------
//
// Compatible TimeFrame
//
//            TimeFrame : 1 min, 2 min, 5 min, 10 min, 15 min and 30 min
//            TimeFrame : 1 hour are possible only if you set open and close market at 00 for minute  Exemple : 800 for 08h00 and 1700 for 17H00


DEFPARAM DRAWONLASTBARONLY = FALSE

BackColorTransparency = (255/100) * Transparence
BorderColorTransparency = (255/100) * (Transparence * 4)

IF OPENTIME = (HeureOuverture*100) then
OpenPrice = Open
OpenD = OpenDay
OPenM = OpenMonth
OpenY = OpenYear
Date1 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + (HeureOuverture*100)
Date2 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + (HeureFermeture*100)
Date3 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + (HeureOuverture*100) +30000
ENDIF

IF Historique THEN
DRAWSEGMENT(DateToBarIndex(Date1), OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255) STYLE(DOTTEDLINE,1)
DRAWRECTANGLE(DateToBarIndex(Date1), OpenPrice+PointsPipsNeutre, DateToBarIndex(Date2), OpenPrice-PointsPipsNeutre) COLOURED(180,200,255,BackColorTransparency) BORDERCOLOR(140,172,255,BorderColorTransparency)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - Prix : #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,MonoSpaced,Standard,12) COLOURED(140,172,255)
ELSE
IF IsLastBarUpdate THEN
DRAWSEGMENT(DateToBarIndex(Date1), OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255) STYLE(DOTTEDLINE,1)
DRAWRECTANGLE(DateToBarIndex(Date1), OpenPrice+PointsPipsNeutre, DateToBarIndex(Date2), OpenPrice-PointsPipsNeutre) COLOURED(180,200,255,BackColorTransparency) BORDERCOLOR(140,172,255,BorderColorTransparency)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - Prix : #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,MonoSpaced,Standard,12) COLOURED(140,172,255)
ENDIF
ENDIF

RETURN

pour le partage

Merci RyanTrading pour ton partage qui comme tu t'en doute me sera fortement utile

Merci beaucoup

J'ai essayer de bidouiller, pour moi, se samedi, l'indicateur pour qu'il intègre le plus haut et le plus bas des bougies dans les time frame d'ouverture EU et US au lieu de la taille en pips mais impossible de les intégrer au code, si quelqu'un s'y connait mieux que moi.

Je me suis aider d'un code de preorealcode qui fait sensiblement la même chose mais que je trouve moins joli.

@max38250
je peux t'aider mais qu'entends-tu par "bougies dans les time frame d'ouverture" ?

l'OPR peut-être ?

Oui l'OPR.
L'indicateur est superbe et je l'utilise quotidiennement mais j'aimerai pourvoir intégrer le + haut et le + bas de 8 à 9H pour qu'il me serve d'OPR

Voici le code:
PS: j'ai initialisé les variables dans le programme
J'ai créé 2 nouvelles variables pour l'OPR:
HeureOuvertureOPR=080000
HeureFermetureOPR=090000

Code : #

// Author : RyanTrading
// Indicator Name : NeutralZone
// ProRealTime Version : 11
// Published for : AndLil

DEFPARAM DRAWONLASTBARONLY = FALSE

HeureOuverture=080000
HeureFermeture=220000
HeureOuvertureOPR=080000
HeureFermetureOPR=090000
Historique=1

if IntradayBarIndex=0 then
lowOPR=0
highOPR=0
endif
if time>=HeureOuvertureOPR and time<=HeureFermetureOPR then
if high>highOPR then
highOPR=high
endif
if low<lowOPR or lowOPR=0 then
lowOPR=low
endif
endif

Drawed = 0

IF OPENTIME >= HeureOuverture and opentime < HeureOuverture + 25  then
OpenPrice = Open
OpenD = openday
OPenM = openmonth
OpenY = openYear
Date1 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + HeureOuverture
Date2 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + HeureFermeture
Date3 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + HeureFermeture -30000
endif

IF OPENTIME >= HeureFermetureOPR and opentime < HeureFermetureOPR + 25  then
IF NOT Drawed[1] THEN

IF Historique=1 THEN

DRAWSEGMENT(BarIndex, OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255)
DRAWRECTANGLE(BarIndex, highOPR, DateToBarIndex(Date2), lowOPR) COLOURED(140,172,255)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,Dialog,standard,12) COLOURED(140,172,255)

ELSE

IF OPENDAY = TODAY then
DRAWSEGMENT(BarIndex, OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255)
DRAWRECTANGLE(BarIndex, highOPR, DateToBarIndex(Date2), lowOPR) COLOURED(140,172,255)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,Dialog,standard,12) COLOURED(140,172,255)
ENDIF

ENDIF

Drawed = 1

ENDIF
ENDIF

RETURN

Merci je regarde ça davantage demain.
Bon dimanche

Il doit être possible d'utiliser le multi time frame et d'entourer le pavé de setup des bornes du rectangles avec
TIMEFRAME(15mn,UpdateOnClose)
...
TIMEFRAME(default)
Mais il faudra ensuite être dans un multiple de ce timeframe 1M, 3m, 15M, 60M, ...

Oui c'est certainement possible tjee.

L'indicateur modifier est bien, mais il ne prend pas en compte le plus et le plus bas de 8 à 9h
Je vais essayer de décortiquer une nouvelle fois et de modifier cela.

Le suivant fonctionne uniquement sur des ut sous-multiples de 15 minutes mais je pense qu'il affiche ton OPR

Code : #

// Author : RyanTrading modified by TJEE
// Indicator Name : Neutral Zone
// ProRealTime Version : 11
// Published for : AndLil - https://www.andlil.com/
// -------------------------------------------------------
//
// Compatible TimeFrame
//
//            TimeFrame : 1 sec, 2 sec, 5 sec, 10 sec, 30 sec, 1 min, 3 min, 5 min, 15 min
//            TimeFrame : 1 hour are possible only if you set open and close market at 00 for minute  Exemple : 800 for 08h00 and 1700 for 17H00


DEFPARAM DRAWONLASTBARONLY = FALSE

BackColorTransparency = (255/100) * Transparence
BorderColorTransparency = (255/100) * (Transparence * 4)

OPRSetted=0
TIMEFRAME (15 MINUTE, UpdateOnClose)
IF OPENTIME = (HeureOuverture*100) then
IF (OPRSetted=0) THEN
OPRSetted=1
OpenPrice = HIGH
ClosePrice = LOW
OpenD = OpenDay
OPenM = OpenMonth
OpenY = OpenYear
Date1 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + (HeureOuverture*100)
Date2 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + (HeureFermeture*100)
Date3 = (OpenY * 10000000000) + (OpenM * 100000000) + (OpenD * 1000000) + (HeureOuverture*100) +30000
ENDIF
ENDIF
TIMEFRAME (default)

IF Historique THEN
DRAWSEGMENT(DateToBarIndex(Date1), OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255) STYLE(DOTTEDLINE,1)
DRAWRECTANGLE(DateToBarIndex(Date1), OpenPrice, DateToBarIndex(Date2), ClosePrice) COLOURED(180,200,255,BackColorTransparency) BORDERCOLOR(140,172,255,BorderColorTransparency)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - Prix : #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,MonoSpaced,Standard,12) COLOURED(140,172,255)
ELSE
IF IsLastBarUpdate THEN
DRAWSEGMENT(DateToBarIndex(Date1), OpenPrice, DateToBarIndex(Date2), OpenPrice) COLOURED(180,200,255) STYLE(DOTTEDLINE,1)
DRAWRECTANGLE(DateToBarIndex(Date1), OpenPrice, DateToBarIndex(Date2), ClosePrice) COLOURED(180,200,255,BackColorTransparency) BORDERCOLOR(140,172,255,BorderColorTransparency)
DRAWTEXT("Ouverture #OpenD#/#OpenM#/#OpenY# - Prix : #OpenPrice#",DateToBarIndex(Date3),OpenPrice+2,MonoSpaced,Standard,12) COLOURED(140,172,255)
ENDIF
ENDIF

RETURN

Il y a un bug quand on passe de 5 minutes à 15 minutes alors que ça fonctionne bien si on est directement en 15 minutes au moment ou on ajoute l'indicateur.
Pas trop le temps de voir pourquoi pour le moment.